Comment soustraire le temps dans Excel

Soustraire l’heure d’une autre heure est utile si vous souhaitez trouver la différence d’heure entre deux heures. Par exemple, si vous voulez trouver le temps qu’il a fallu pour terminer une tâche, vous pouvez entrer les heures de début et de fin de la tâche et les soustraire pour trouver le temps total écoulé.

Étant donné qu’Excel stocke les dates et les heures sous forme de nombres, vous pouvez facilement soustraire à l’aide de formules arithmétiques simples, de la fonction TIME, de la fonction TEXT ou de la fonction TIMEVALUE pour calculer le décalage horaire ou le temps écoulé, etc. Dans cet article, nous verrons plusieurs méthodes pour soustraire le temps et calculer la différence entre les dates et les heures dans Excel.

Calculer la différence de temps entre deux heures

Plus que souvent, nous devons calculer la différence de temps entre deux heures données pour trouver le temps écoulé. Vous pouvez calculer le temps entre deux heures ou deux cellules avec une simple soustraction.

Le moyen le plus simple de trouver le décalage horaire consiste à soustraire l’heure de début de l’heure de fin :

=End Time - Start Time

Par exemple, pour soustraire le temps en A3 du temps en B3, nous pouvons utiliser la formule ci-dessous :

=B3-A3

Où A3 est l’heure de début et B3 est l’heure de fin. Comme vous pouvez le voir, il y a 5 heures d’écart entre A3 et B3.

Cependant, si le format de la cellule de résultat est défini sur Général, vous obtiendrez les résultats en fractions/décimales. C’est parce que les valeurs de temps sont représentées sous forme de fractions d’un nombre dans Excel.

Dans le système de date Excel, l’heure est stockée comme ceci :

Dans le système interne d’Excel :

  • 00:00:00 AM est stocké sous 0.0
  • 06:00 AM est enregistré sous 0,25
  • 12:00 PM est stocké sous la forme 0,5
  • 18:00 PM est enregistré sous 0,75
  • 23:59:59 est stocké sous la forme 0.99999

Lorsque vous entrez la date et l’heure dans une cellule, elles seront stockées sous la forme d’un numéro de série composé d’un nombre entier et d’un nombre décimal. Alors que l’entier représente le jour/la date, le nombre après la virgule représente l’heure. Par exemple, lorsque vous tapez “15 ​​août 2001, 06:00:00” dans une cellule Excel, il sera stocké sous la forme “37118.25”.

Ainsi, les 5 heures seront affichées sous la forme ‘0.208333333’ comme indiqué ci-dessous.

Pour afficher les décimales dans le temps, sélectionnez la cellule de sortie. Ensuite, cliquez sur le menu déroulant “Format de nombre” dans le groupe “Numéro” et sélectionnez l’option “Heure”.

Pour appliquer le format d’heure personnalisé, cliquez sur le bouton fléché (Format de nombre) dans le coin du groupe Nombre sur le ruban ou appuyez sur Ctrl1pour ouvrir la boîte de dialogue Format de cellule.

Sous l’onglet Nombre, allez dans l’onglet ‘Heure’ et choisissez l’un des formats d’heure et cliquez sur ‘OK’.

Vous pouvez également accéder à l’onglet “Personnalisé” et saisir l’un des codes suivants, puis cliquer sur “OK” pour appliquer le format d’heure correspondant :

CODE TEMPORELUTILISATION
hPour afficher le décalage horaire en heures. Par exemple 5
hmmPour afficher le décalage horaire en heures et minutes. Par exemple 5:30
h:mm:ssPour afficher les décalages horaires en heures, minutes et secondes. Par exemple 5:30:10
dh:mm:ssPour afficher les décalages horaires en jours, heures, minutes et secondes. Ex. 2 5:30:10

Si la sortie est une erreur #####, cela signifie soit que la cellule de sortie n’est pas assez large, soit que le résultat est un nombre négatif. Si le résultat est négatif, nous verrons comment gérer les temps négatifs dans Excel dans l’une des sections suivantes.

Compter les heures, les minutes ou les secondes entre deux heures

Parfois, nous voulons uniquement calculer le décalage horaire en unités de temps individuelles (heures, minutes ou secondes). Lorsque vous soustrayez des heures, Excel renverra toujours des nombres décimaux. Dans la valeur résultante, chaque nombre entier représente un jour et les nombres décimaux peuvent être convertis en heures, minutes ou secondes. Pour cela, utilisez les formules suivantes :

Trouver des heures entre deux heures

Pour calculer la différence de temps entre deux heures en heures, utilisez cette formule :

=(End time - Start time) * 24

Exemple:

=(B3-A3) * 24

Ici, l’heure de début est A3 et l’heure de fin est B3. Vous pouvez soustraire B3-A3pour calculer la différence entre les deux heures, puis la multiplier par 24 (qui est le nombre d’heures dans une journée). Cela nous donne 10,17 comme résultat.

Vous pouvez utiliser la fonction INT pour obtenir le nombre d’heures complètes :

=INT((B3-A3) * 24)

La fonction INT arrondit le résultat pour donner des nombres entiers.

Trouver le nombre total de minutes entre deux heures

Pour calculer la différence de temps entre deux heures en minutes, utilisez cette formule :

=(End time - Start time) * 1440

ou

=(End time -Start time ) * 24 * 60

Exemple:

=(B3-A3) * 1440

Où l’heure de début est A3 et l’heure de fin est B3. Vous pouvez utiliser une simple soustraction B3-A3pour trouver la différence entre les deux temps, puis la multiplier par 1440 qui est le nombre de minutes dans une journée. La sortie finale sera 610, soit le nombre total de minutes entre A3 et B3.

Trouver le nombre total de secondes entre deux heures

Utilisez cette formule pour obtenir la différence entre deux temps en secondes :

=(End time - Start time) * 86400

ou

=(End time - Start time) * 24 * 60 * 60

Exemple:

=(B3-A3) * 86400

Où l’heure de début est A3 et l’heure de fin est B3. Vous pouvez utiliser une simple soustraction B3-A3pour trouver la différence entre les deux temps, puis la multiplier par 86400 qui est le nombre de secondes dans une journée. La sortie finale sera 36600, qui est le nombre total de secondes entre A3 et B3.

Calculer le temps écoulé depuis une heure de début jusqu’à maintenant à l’aide de la fonction Now ()

Lorsque vous utilisez la fonction MAINTENANT dans Excel, elle affichera la date et l’heure actuelles de votre ordinateur. Si vous souhaitez trouver le temps écoulé depuis une heure de début jusqu’à maintenant, c’est-à-dire l’heure actuelle, vous pouvez utiliser la fonction Now() au lieu de l’heure de fin dans la formule.

Voici une formule que vous pouvez utiliser pour trouver le temps écoulé :

=Now-Start time

Dans l’exemple ci-dessous, l’heure de début est dans la colonne A. Pour calculer le temps écoulé depuis l’heure de début donnée jusqu’à maintenant, vous pouvez utiliser la formule :

=NOW()-A1

La valeur résultante pour le temps écoulé jusqu’à présent est renvoyée dans la colonne B. Si vos heures de début n’ont que des unités de temps sans dates, la formule peut renvoyer des résultats erronés, comme indiqué ci-dessous. C’est parce qu’Excel considérera la date comme le 1er janvier 1990 par défaut.

Pour résoudre ce problème, vous pouvez soit ajouter la partie date à l’heure de début, soit utiliser la fonction INT() qui réduira la valeur du jour renvoyée par la fonction NOW().

READ  Comment utiliser Excel SUMIF avec plusieurs critères

Entrez d’abord la date et l’heure de début dans une ou plusieurs cellules, puis entrez la même formule. Assurez-vous d’appliquer le format d’heure approprié à la colonne C (colonne de résultat),  h:mm.

Si le temps écoulé dépasse 24 heures, vous devez appliquer le format d’heure pour afficher les jours ainsi que l’heure dans le résultat. Vous pouvez utiliser l’un des formats suivants pour inclure les jours :

FormatExemple
dh:mm:ss1 15:57:29
j “jour” h:mm:ss1 jour 15:57:29
d « jour », h « heures », m « minutes » et » s « secondes »1 jour 15 heures 57 minutes et 29 secondes

Dans l’exemple ci-dessous, nous avons appliqué le d "day" h:mm:ssformat à la colonne C. Comme vous pouvez le voir, le temps écoulé depuis l’heure de début (29/07/2022) jusqu’à maintenant est de 1 jour 15 heures, 57 minutes et 29 secondes.

Calculer la différence de temps entre les heures spécifiées

Vous pouvez calculer directement la différence de temps entre deux heures données à l’aide de la fonction TIMEVALUE(). Avec la fonction TIMEVALUE, vous n’avez pas besoin d’entrer les heures de début et de fin dans deux cellules différentes, vous pouvez transmettre les valeurs directement à la formule.

La syntaxe :

=TIMEVALUE("Start Time") - TIMEVALUE("End Time")

Par exemple, pour calculer le décalage horaire entre 6h10 et 3h00, utilisez la formule ci-dessous :

=TIMEVALUE("6:10 PM")-TIMEVALUE("3:00 PM")

Calculer la différence dans une seule unité de temps

Vous pouvez utiliser les fonctions HOUR(), MINUTE() et SECOND() pour calculer la différence de temps entre deux heures dans une seule unité tout en ignorant les autres.

Pour calculer le décalage horaire en heures en ignorant les minutes et les secondes, utilisez cet exemple de formule :

=HOUR(A2-B2)

Pour calculer le décalage horaire en minutes sans tenir compte des minutes et des secondes, utilisez cet exemple de formule :

=MINUTE(A2-B2)

Pour calculer le décalage horaire en secondes tout en ignorant les minutes et les secondes, utilisez cet exemple de formule :

=SECOND(A2-B2)

Cependant, si l’heure de fin est inférieure à l’heure de début, le résultat sera un nombre négatif. Ainsi, vous obtiendrez un NUM! erreur en conséquence.

Assurez-vous que le résultat de la fonction HOUR() ne sort pas 24 heures et que le résultat des fonctions MINUTE() et SECOND() ne sort pas respectivement 60 minutes et 60 secondes.

Soustraire le temps pour trouver la différence de temps à l’aide de la fonction de texte

Si vous ne souhaitez pas modifier le format des cellules, vous pouvez utiliser la fonction TEXTE pour calculer et afficher le décalage horaire sous forme de chaîne de texte. Avec la fonction TEXT, vous n’avez pas besoin d’appliquer de formatage aux cellules, vous pouvez simplement spécifier le format de la sortie directement dans la formule.

La syntaxe pour calculer le décalage horaire :

=TEXT(End Time - Start Time,"format")

Décalage horaire en heures entre deux heures

Pour obtenir uniquement les heures écoulées entre les deux heures :

=TEXT(B2-A2,"hh")

Dans ce qui précède, hhreprésente l’unité d’heure. Comme vous pouvez le voir, la formule soustrait le temps en B2 de A2, puis ne produit que le nombre d’heures écoulées entre les heures de début et de fin.

Différence de temps en minutes entre deux heures

Pour obtenir uniquement les minutes écoulées entre les deux temps, essayez cette formule :

=TEXT(B2-A2,"[mm]")

Où [mm] représente le nombre total de minutes. Comme vous pouvez le voir, la formule soustrait le temps en B2 de A2, puis ne produit que le nombre de minutes écoulées entre deux temps.

Différence de temps en secondes entre deux heures

Pour obtenir uniquement les secondes écoulées entre les deux temps, utilisez cette formule :

=TEXT(B2-A2,"[ss]")

Où [ss]représente le nombre total de secondes. La formule soustrait l’heure de fin de l’heure de début et renvoie uniquement le nombre total de secondes.

Vous avez probablement remarqué que les formats ‘mm’ et ‘ss’ sont entre crochets, c’est parce que nous voulons obtenir le nombre total de minutes ou de secondes entre les deux heures et pas seulement les minutes ou secondes restantes en plus des heures. Cependant, si le nombre d’heures est supérieur à 24 heures, vous pouvez utiliser le format ‘[hh]’ (entre crochets) dans la formule.

Pour trouver les minutes restantes entre deux heures en plus des heures, utilisez plutôt la formule ci-dessous

=TEXT(B2-A2,"mm")

Pour trouver les secondes restantes entre deux heures en plus des heures, utilisez plutôt la formule ci-dessous

=TEXT(B2-A2,"ss")

Pour renvoyer les trois heures, minutes et secondes entre deux heures, utilisez cette formule :

=TEXT(B2-A2,"hh:mm:ss")

Remarque : Le résultat renvoyé par la fonction TEXT est toujours un TEXT. Par conséquent, la sortie ne peut pas être utilisée dans d’autres calculs. Si vous avez l’intention d’utiliser le temps calculé dans d’autres calculs, utilisez l’une des autres méthodes pour calculer la différence de temps.

Si la valeur renvoyée par la fonction TEXT est un nombre négatif, vous obtiendrez #VALUE ! Erreur.

Calculer la différence de temps entre deux dates

Avant de commencer, vous devez savoir qu’Excel stocke les données et l’heure sous forme de numéros de série. Lorsque vous entrez une date dans une cellule Excel, elle attribue un numéro de série et si vous entrez une heure, elle attribue une fraction de nombre.

Excel dispose d’un système de numéros de série avec des dates allant du 1er janvier 1900 à ce jour et au-delà. Cela signifie que le 1er janvier 1900 est 1, le 2 janvier 1900 est 2, le 3 janvier 1900 est 3, et ainsi de suite. Par exemple, le numéro de série pour la date 01/08/2022 est 44774 et la fraction ou le nombre décimal pour 6h00 est 0,25 (quart de jour).

Cependant, certaines versions antérieures d’Excel pour Mac utilisent le système de date 1904. Vous avez également la possibilité d’activer le système de date 1904. Dans de tels cas, le numéro de série commencera au 1er janvier 1904 (0). Et le 2 janvier 1904 est 2, 3 janvier 1904, et ainsi de suite.

Calculer la différence de temps entre deux dates en heures

Pour calculer le décalage horaire entre deux dates et heures, vous pouvez utiliser la formule ci-dessous :

=INT((B2 – A2) * 24) & " hours"

Où B2 est la date de fin et A2 est la date de début. La formule (B2-A2) produira une fraction. Nous devons ajouter le nombre de jours + la fraction pour obtenir la différence en heures.

Voyons comment fonctionne cette formule :

Comme vous pouvez le voir, la différence totale entre les deux dates (lorsque vous avez appliqué le format d’heure ‘dh:mm:ss’ à la cellule de sortie) est de 2 jours, 5 heures, 59 minutes et 40 secondes.

Vous pouvez appliquer ce formatage personnalisé ‘dh:mm:ss’ dans la boîte de dialogue Formater les cellules.

Excel calculera en termes de jours et nous montrera qu’il y a 2 jours de différence entre les dates soit 48 heures. Cela nous laisse avec 5 heures, 59 minutes et 40 secondes. Maintenant, nous devons également ajouter ceci dans la sortie.

Pour ce faire, nous devons convertir les 5 heures, 59 minutes et 40 secondes en termes de jours. Puisque notre temps se termine en secondes, nous calculerons les 5 heures, 59 minutes et 40 secondes en termes de secondes comme indiqué ci-dessous :

  • 5 heures * 60 minutes * 60 secondes = 18 000 secondes
  • 59 minutes * 60 secondes = 3 540
  • 40 secondes
  • 5 heures, 59 minutes et 40 secondes = 18 000 secondes + 3 540 secondes + 40 secondes = 21 580 secondes.
READ  Gagnez du temps dans la saisie de données en utilisant Flash Fill dans Excel

Pour calculer la décimale du jour, nous devons diviser le total ci-dessus de 21 580 secondes par 86 400 secondes (c’est-à-dire le nombre total de secondes en 1 jour).

  • 21 580 / 86 400 = 0,249769 jours

En conséquence, la fraction que nous obtiendrons est de 0,249769 jours.

Maintenant, la différence finale entre les deux dates est de 2 jours + 0,249769 = 2,2497685.

Alternativement,

  • Le numéro de série de Start DateTime (01/08/2022 14:15:50) est 44774.59433.
  • Le numéro de série pour End DateTime (03/08/2022 20:15:30) est 44776.8441.
  • DateHeure de fin (B2) – DateHeure de début (A2) = 44774.59433 – 44776.8441 = 2.2497685.

Pour convertir la sortie ci-dessus en heures, multipliez-la par 24 :

  • 2,2497685 * 24 = 53,994444 heures.

Enfin, la fonction INT supprime les décimales à la fin et l’opérateur ‘&’ ajoute la chaîne de texte (heures) à la fin pour donner le nombre total d’heures entre les deux jours, soit ’53 heures’.

Calculer la différence de temps entre deux dates en minutes

Le calcul du décalage horaire entre deux dates en minutes est similaire au calcul des heures, la seule différence est que vous devez multiplier le décalage horaire par 1440 (nombre de minutes par jour) dans la formule. Ensuite, ajoutez la chaîne de texte ‘minutes’ à la fin au lieu de ‘heures’.

Pour calculer la différence de temps entre deux dates en termes de minutes :

=INT((B2 - A2) * 1440) &" minutes"

Où B2 est EndDate et A2 est StartDate. Dans la formule ci-dessus, la différence de temps de sortie de soustraction entre deux dates est multipliée par 1440 (le nombre de minutes dans 1 jour). Et puis la chaîne ‘minutes’ est ajoutée au résultat.

Calculer la différence de temps entre deux dates en secondes

Le calcul des secondes est identique au calcul des heures et des minutes, la seule différence est que vous multiplierez la sortie de soustraction par 86400 (nombre de secondes dans une journée).

Pour ce faire, vous pouvez utiliser la formule ci-dessous :

=INT((B2 - A2) * 86400) &" seconds"

La formule soustrait le Datetime dans B2 de A2, puis multiplie le résultat par 86400 (nombre de secondes en une seule journée) car nous voulons le résultat en termes de secondes. Cela produira 194379 comme résultat. Puisqu’il n’y a pas de valeurs décimales, la fonction INT renverra la même sortie (nombre total de secondes entre deux dates).

Calculer tous les jours, heures, minutes et secondes entre deux dates

Si vous souhaitez obtenir le décalage horaire entre deux dates en termes de jours, heures, minutes et secondes, vous devez utiliser la fonction TEXT avec la fonction INT.

Pour calculer les jours, les heures, les minutes et les secondes entre deux dates, essayez la formule ci-dessous :

=INT(B2-A2) & " days, "& TEXT(B2-A2,"h"" hours, ""m"" minutes, and ""s"" seconds""") 

Ici, la première partie de la formule fonctionne de la même manière que dans les exemples précédents. La fonction INT renvoie une valeur entière générée en soustrayant les dates données (2,2497685) qui est de 2 jours.

Dans la deuxième partie de la formule, la fonction TEXTE soustrait les deux dates, puis applique une mise en forme numérique personnalisée au résultat (5:59:40 AM). Le "h"format renvoie le nombre d’heures, "m"renvoie le nombre de minutes et "s"renvoie le nombre de secondes. La fonction TEXT ajoute également les chaînes entre guillemets heures, minutes et secondes après chaque unité de temps.

Enfin, les sorties des fonctions INT et TEXT sont combinées à l’aide de l’opérateur de concaténation (&) pour donner ce résultat : 2 jours, 5 heures, 59 minutes et 40 secondes.

Comme vous l’avez peut-être remarqué, nous avons ajouté un espace après chaque chaîne de texte dans la formule. Assurez-vous d’ajouter ces espaces pour éviter que les résultats ne se confondent.

Alternativement, vous pouvez également utiliser la fonction INT avec des fonctions HOUR, MINUTE et SECOND séparées pour obtenir les mêmes résultats :

=INT(B2-A2) & " days, " & HOUR(B2-A2) & " hours, " & MINUTE(B2-A2) & " minutes and " & SECOND(B2-A2) & " seconds"

Soustraire des heures, des minutes ou des secondes d’une heure spécifique

Parfois, nous pouvons vouloir soustraire certains intervalles de temps (Heures, Minutes, Secondes) d’une heure spécifique ou DateTime. Vous pouvez y parvenir avec ou sans la fonction TIME dans Excel. Si les heures que vous souhaitez soustraire sont inférieures ou égales à 23, vous pouvez utiliser la formule TIME. Mais il existe une autre formule qui peut être utilisée pour soustraire n’importe quel nombre d’heures.

Soustraire des heures d’une heure sans fonction TIME

Par exemple, si vous avez une date et une heure particulières et que vous souhaitez calculer une heure qui était un certain nombre d’heures auparavant, vous pouvez diviser les heures que vous souhaitez soustraire par le nombre total d’heures (par jour), puis soustraire le résultat. à partir du moment donné.

=Given Time/DateTime - (Hours to be subtracted/24)

Exemple:

=A2 - (18 / 24)

Voici comment la formule fonctionne :

Excel calcule la différence en termes de jours, nous devons donc fournir à Excel le nombre de jours (ou fraction) de jours que nous voulons soustraire de la date ou de l’heure donnée (A2).

Pour calculer les jours, vous devez diviser les heures que vous souhaitez soustraire par 24 (nombre total d’heures par jour) – 18/24. Cela nous donnera 0,75. Si vous souhaitez soustraire plus de 24 heures, le nombre avant la virgule représente les jours et la valeur après la virgule représente le temps.

Maintenant, Excel soustraira 0,75 du (44774,59433) qui est le numéro de série du 01/08/2022 14:15:50 (A2) car Excel pense en termes de fractions et de décimales.

Cela renverra 44773.84433 qui est le numéro de série pour ‘7/31/22 8:15 PM’. Par conséquent, la sortie est 31/07/22 20:15.

Exemple 2 :

Supposons que vous vouliez remonter 42 heures dans le temps à partir du 1er août 2022, 18h00. Nous devons donc fournir à Excel le nombre de jours que nous voulons soustraire de l’heure donnée.

Pour convertir les heures en jours, nous devons diviser 42 par 24 puis le soustraire de A2 :

=A2-(42/24)

En divisant 42 par 24, nous obtiendrons 1,75 jours. Comme nous l’avons mentionné précédemment, le nombre avant la virgule représente les jours (1) et la fraction après la virgule représente les heures (0,75).

En multipliant 0,75 par 24 (0,75*24), nous obtiendrons 18 heures. Ainsi, Excel soustraira 1 jour 18 heures de A2 (1er août 2022, 18h00). La sortie finale est 30/07/22 20h15.

Bien que la formule arithmétique simple ci-dessus puisse être utilisée pour n’importe quel nombre d’heures à partir de l’heure donnée, vous pouvez utiliser la formule TIME si les heures à soustraire sont inférieures ou égales à 23.

Soustraire des heures d’une heure à l’aide de la fonction TIME

La fonction TIME vous permet de convertir une seule valeur de temps en unités individuelles d’heure, de minute et de seconde. Il peut également être utilisé pour fusionner des unités de temps individuelles en une seule valeur de temps. Cependant, la fonction TIME ne peut gérer qu’un maximum de 23 heures, 59 minutes et 59 secondes.

READ  Comment supprimer des lignes vides dans Excel : les 3 meilleures méthodes

Syntaxe:

= Given Time/DateTime - TIME(Hours to be subtracted, 0, 0)

Exemple:

Pour remonter de 18 heures dans le temps à partir du soir du 15 août 2022 (18 h 00), utilisez la formule TIME suivante :

=A2 – TIME (18, 0, 0)

La fonction TIME a trois arguments : heure, minute et seconde. Nous voulons soustraire 18 heures, donc le premier argument est ’18’, et les deux autres arguments – minute et seconde sont spécifiés comme ‘0’.

Habituellement, la fonction TIME renvoie une sortie entre 0 (0:00:00 ou 12:00:00 AM) et 0,99988426 (23:59:59 PM). Dans la formule ci-dessus, il renvoie 0,75 qui est soustrait de A2.

Soustraire des minutes d’un DateTime

Nous pouvons utiliser les mêmes formules ci-dessus pour soustraire les minutes et la seule différence est que nous devons diviser les minutes à soustraire par 1440.

= A2 - (4500/1440)

Dans la formule ci-dessus, le nombre de minutes que nous voulons soustraire (4500) est divisé par le nombre total de minutes en 1 jour (1440) pour convertir les minutes en jours. La division renverra 3,125 jours qui, une fois soustraits de A2, et nous obtiendrons la sortie de ‘7/29/22 3:00 PM’.

Soustraction de minutes d’une heure spécifique à l’aide de la fonction TIME

Vous pouvez également utiliser la fonction TIME pour soustraire des minutes d’une heure spécifique tant que le temps à soustraire est inférieur ou égal à 1439 en raison de la limitation de la fonction TIME. Il ne peut gérer que 23 heures, 59 minutes et 59 secondes, soit un total de 1439 minutes. Si vous souhaitez soustraire plus de 1439 minutes, vous devez utiliser la formule arithmétique ci-dessus.

Pour soustraire 900 minutes du temps donné à l’aide de la fonction TIME :

=A2 - TIME(0,900,0)

Dans la formule ci-dessus, les minutes (900) que nous voulons soustraire sont spécifiées dans le deuxième argument de la fonction TIME. Cela nous donne le 01 août 2022, 3h00 du matin.

Soustraire des secondes d’un DateTime

Nous pouvons utiliser les mêmes formules ci-dessus pour soustraire les secondes et la seule différence est que le dénominateur entre parenthèses est 86400.

Syntaxe:

= A2 - (seconds to be subtracted / 86400)

Dans la formule ci-dessus, le nombre de secondes que nous voulons soustraire (10000) est divisé par le nombre total de secondes en 1 jour (24 heures * 60 minutes * 60 secondes = 86400) pour convertir les secondes en jours. La division renverra 0,115740741 jours qui, une fois soustraits de A2, nous obtiendrons ‘8/1/22 3:13 PM’.

Soustraction de secondes d’une heure spécifique à l’aide de la fonction TIME

Encore une fois, vous pouvez également utiliser la fonction TIME pour soustraire des secondes d’un temps spécifique tant que le temps à soustraire est inférieur ou égal à 86399 en raison de la limitation de la fonction TIME. Il ne peut gérer que 23 heures, 59 minutes et 59 secondes, soit un total de 86 399 minutes. Si vous souhaitez soustraire plus de 86399 secondes, vous devez utiliser la formule arithmétique ci-dessus.

Pour soustraire 9000 secondes du temps donné en utilisant la fonction TIME :

=A2 - TIME(0,9000,0)

Dans la formule ci-dessus, les secondes (9000) que nous voulons soustraire sont spécifiées dans le deuxième argument de la fonction TIME. Cela nous donne le 01 août 2022, 15h30.

Soustraction d’heures, de minutes et de secondes d’une heure spécifique à l’aide de la fonction TIME

Si vous souhaitez soustraire des heures, des minutes et des secondes d’une certaine date, la fonction TIME peut vous aider.

Par exemple, pour soustraire 2 heures, 15 minutes et 30 secondes, essayez la formule ci-dessous :

=A2 - TIME(2,15,30)

Dans la formule ci-dessus, nous avons spécifié les trois unités de temps – heures, minutes et secondes dans les arguments de la fonction TIME. Ainsi, la formule soustrait 2 heures, 15 minutes et 30 secondes de A2 (01/08/22 18:00:00). Cela nous donnera 01/08/22 15h44.

Calcul des temps négatifs dans Excel

Lorsque vous soustrayez l’heure si l’heure de fin est inférieure à l’heure de début, vous obtiendrez un nombre négatif dans le décalage horaire. La formule donnera des nombres négatifs si le décalage horaire est inférieur à 0. Cela se produit généralement lorsque vous ne saisissez que des heures dans une feuille de calcul sans dates.

De plus, si vous travaillez habituellement de nuit, l’heure et la date de fin seront toujours antérieures à la date et à l’heure de début de votre travail. Par exemple, si vous commencez votre travail à 18 h 00, que vous finissez votre travail et que vous vous déconnectez le lendemain matin à 6 h 00, la méthode de soustraction habituelle ne fonctionnera pas.

Comme vous pouvez le voir ci-dessous, non seulement la formule ne le sera pas, mais Excel vous lancera l’erreur ###### lorsque vous avez un temps négatif.

Cependant, si vous souhaitez quand même afficher le négatif, vous pouvez simplement passer au système de date 1904. La plupart des versions modernes d’Excel utilisent par défaut le système de date 1900, mais si vous modifiez le système de date en 1900, vous pouvez afficher les valeurs temporelles négatives.

Voici comment passer au système de date 1904 dans MS Excel :

Pour ce faire, cliquez sur le menu ‘Fichier’ dans la fenêtre Excel, puis sélectionnez ‘Options’ dans la vue backstage.

Dans la fenêtre Options Excel, accédez à l’onglet “Avancé” sur la gauche, puis faites défiler jusqu’à la section “Lors du calcul de ce classeur”. Ensuite, cochez la case “Utiliser le système de date 1904” et cliquez sur “OK”.

Maintenant, Excel affichera les valeurs de date et d’heure négatives comme indiqué ci-dessous :

Si vous souhaitez afficher l’heure en valeurs négatives, vous pouvez utiliser la fonction SI pour forcer les heures négatives à s’afficher correctement.

Vous pouvez utiliser l’une des formules suivantes pour afficher correctement les heures négatives lorsque les heures traversent minuit :

=IF((B3-A3)<0,1-(A3-B3),(B3-A3))

ou

=IF(B3>A3,B3-A3,1-A3+B3)

La formule ci-dessus calculera la différence de temps négative et l’affichera correctement comme indiqué ci-dessous.

Cependant, la formule ci-dessus fonctionnera dans la plupart des cas. Si le décalage horaire est supérieur à 24 heures, les formules ci-dessus ne fonctionneront pas non plus. Dans de tels cas, assurez-vous d’inclure les dates avec les heures.

Soustraire les dates pour compter les jours intermédiaires

Semblable au temps, vous pouvez également soustraire deux cellules avec des dates pour trouver le nombre de jours entre deux dates.

Par exemple, les cellules A3 et B3 contiennent deux dates. Pour trouver la différence en jours, utilisez la formule ci-dessous :

=B3-A3

La formule renvoie la différence entre deux dates A3 et B3 sous la forme de 132 jours.

Compter les jours entre deux dates à l’aide de la fonction JOURS

Outre la simple soustraction de cellules, vous pouvez également utiliser la fonction JOURS pour calculer la différence entre deux dates.

La syntaxe

 =DAYS(End date, Start Date)

Exemple:

=DAYS(B3,A3)

Où B3 est la date de fin et A3 est la date de début.


C’est la fin. Vous savez maintenant tout ce que vous devez savoir sur la soustraction de temps dans Excel et plus encore. Espérons que la connaissance de ces fonctions augmentera votre productivité dans Excel.

5/5 - (1 vote)
SAKHRI Mohamed
SAKHRI Mohamed

Le blog d'un passionné d'informatique qui partage des actualités, des tutoriels, des astuces, des outils en ligne et des logiciels pour Windows, macOS, Linux, Web designer et jeux vidéo.

Publications: 3732

Laisser un commentaire

Your email address will not be published.